SAS对数据缺失值的插补方法

坚强别无选择

1. 
   
2. /**读入数据，生成SAS数据集work.Air**/
   
3. data Air;
   
4.   infile 'E:\data\ch3_air.csv' delimiter=',' firstobs=2;
   
5.   informat Ozone best32.;
   
6.   informat SolarR best32.;
   
7.   informat Temp best32.;
   
8.   informat Wind best32.;
   
9.   format Ozone best32.;
   
10.   format SolarR best32.;
    
11.   format Temp best32.;
    
12.   format Wind best32.;
    
13.   input Ozone SolarR Temp Wind;
    
14. run;
    
15. proc print data=Air(obs=10);
    
16. run;
    
17. 
    
18. /**画每个变量的直方图，并查看其总观测数、最小值、下四分位数、
    
19.    中位数、上四分位数、最大值、缺失观测数**/
    
20. proc univariate data=Air ;
    
21.    histogram Ozone / cbarline=grey cfill=ligr;
    
22.      inset n nmiss mean std min Q1 median Q3 max /
    
23.        header='Descriptive Statistics' pos=ne noframe;
    
24.    histogram SolarR / cbarline=grey cfill=ligr;
    
25.      inset n nmiss mean std min Q1 median Q3 max /
    
26.        header='Descriptive Statistics' pos=ne noframe;
    
27.    histogram Wind / cbarline=grey cfill=ligr;
    
28.      inset n nmiss mean std min Q1 median Q3 max /
    
29.        header='Descriptive Statistics' pos=ne noframe;
    
30.    histogram Temp / cbarline=grey cfill=ligr;
    
31.      inset n nmiss mean std min Q1 median Q3 max /
    
32.        header='Descriptive Statistics' pos=ne noframe;
    
33. run;
    
34. /*观察到Ozone和SolarR分别有37和7个缺失值*/
    
35. 
    
36. /**寻找每个变量的最合适的Box-Cox变换，将其变换为正态分布。
    
37.    以便后面的插补程序使用。**/
    
38. data Air2;
    
39.    set Air;
    
40.    const=1;
    
41.    /*在数据集Air中加一个值总是等于1的变量const，存为数据集Air2*/
    
42. run;
    
43. proc transreg data=Air2;
    
44.    /*transreg过程可用来选择线性回归中因变量的最佳Box-Cox变换*/
    
45.    model BoxCox(Ozone / lambda=-3 to 3 by .1) = identity(const);
    
46.    /*以Box-Cox变换后的Ozone为因变量，const为自变量做线性回归，
    
47.      选取因变量的最佳变换，使似然函数最大化。
    
48.      因为const是常数，在线性回归时会自动去掉，线性回归相当于
    
49.        对Box-Cox变换后的Ozone拟合正态分布。
    
50.      Box-Cox变换的参数从-3到3、步长为0.1的一系列数中选择*/
    
51. run;
    
52. 
    
53. proc transreg data=Air2;
    
54.    model BoxCox(SolarR / lambda=-3 to 3 by .1) = identity(const);
    
55. run;
    
56. /*对SolarR变量进行Box-Cox变换的最佳参数值为1*/
    
57. 
    
58. proc transreg data=Air2;
    
59.    model BoxCox(Wind / lambda=-3 to 3 by .1) = identity(const);
    
60. run;
    
61. /*对Wind变量进行Box-Cox变换的最佳参数值为2.2*/
    
62. 
    
63. proc transreg data=Air2;
    
64.    model BoxCox(Temp / lambda=-3 to 3 by .1) = identity(const);
    
65. run;
    
66. /*对Temp变量进行Box-Cox变换的最佳参数值为0.7*/
    
67. 
    
68. /**将Ozone的最小值存入宏变量minOzone，最大值存入宏变量maxOzone；
    
69.    将SolarR的最小值存入宏变量minSolarR，最大值存入宏变量maxSolarR**/
    
70. proc sql noprint;
    
71.   select min(Ozone), max(Ozone), min(SolarR), max(SolarR)
    
72.     into :minOzone, :maxOzone, :minSolarR, :maxSolarR
    
73.   from Air;
    
74. quit;
    
75. 
    
76. /**对work.Air数据集进行多重插补**/
    
77. proc mi
    
78.   data=Air out=mi_Air nimpute=5 round=1
    
79.   minimum=&minOzone. &minSolarR. maximum=&maxOzone. &maxSolarR.;
    
80.   /*被插补的数据集为Air，插补结果存入数据集work.mi_Air，nimpute=5指定进行5次插补。
    
81.     因为存在缺失值的变量Ozone和SolarR的取值均为整数，所以round=1指定插补结果取整数。
    
82.     minimum语句说明限定Ozone插补结果的最小值为宏变量minOzone的值，
    
83.     SolarR插补结果的最小值为宏变量minSolarR的值。
    
84.     maximum语句说明限定Ozone插补结果的最大值为宏变量maxOzone的值，
    
85.     SolarR插补结果的最大值为宏变量maxSolarR的值。*/
    
86.   Transform boxcox(Ozone/lambda=0.2)
    
87.             boxcox(Wind/lambda=2.2)
    
88.             boxcox(Temp/lambda=0.7);
    
89.   /*根据前面选取最合适的Box-Cox变换的结果，
    
90.     在插补时对Ozone变量进行参数为0.2的Box-Cox变换，
    
91.     对Wind变量进行参数为2.2的Box-Cox变换，
    
92.     对Temp变量进行参数为0.7的Box-Cox变换*/
    
93.   var Ozone SolarR Wind Temp;
    
94.   /*指明在插补模型中使用所有四个变量*/
    
95. run;
    
96. /*插补后的数据集work.mi_Air中将包含一个变量_Imputation_，说明是第几次插补的结果。
    
97.   对每次插补，该数据集还将给出插补后所有观测的所有变量的值。*/
    
98. 
    
99. /**对插补后的数据集work.mi_Air进行综合分析，
    
100.    估计Ozone和SolarR这两个变量的总体均值，并得到估计的标准误差**/
     
101. proc univariate data=mi_Air;
     
102.   var Ozone;
     
103.   by _Imputation_;
     
104.   /*针对每次插补数据集分别分析Ozone变量*/
     
105.   output out=mi_Ozone_results mean=Ozone_mean stderr=Ozone_stderr;
     
106.   /*获得每次插补数据集Ozone变量的样本均值及均值的标准误差，
     
107.     存入数据集mi_Ozone_results*/
     
108. run;
     
109. proc mianalyze data=mi_Ozone_results;
     
110.   /*综合mi_Ozone_results各次插补数据集的分析结果*/
     
111.   modeleffects Ozone_mean;
     
112.   /*说明每次插补数据集的参数估计由Ozone_mean变量给出*/
     
113.   stderr Ozone_stderr;
     
114.   /*说明每次插补数据集的参数估计的标准误差由Ozone_stderr变量给出*/
     
115. run;
     
116. 
     
117. proc univariate data=mi_Air;
     
118.   var SolarR;
     
119.   by _Imputation_;
     
120.   output out=mi_SolarR_results mean=SolarR_mean stderr=SolarR_stderr;
     
121. run;
     
122. proc mianalyze data=mi_SolarR_results;
     
123.   modeleffects SolarR_mean;
     
124.   stderr SolarR_stderr;
     
125. run;

复制代码

karstification

谢谢你的数据，谢谢你的分享！